home *** CD-ROM | disk | FTP | other *** search
/ Amiga Developer CD 2.1 / Amiga Developer CD v2.1.iso / NDK / NDK_1.3 / Include-Strip1.3 / startups / startup1.3 / oldrstart / Rstartup.asm < prev    next >
Encoding:
Assembly Source File  |  1988-08-01  |  20.8 KB  |  726 lines
  1.  
  2. *------ Rstartup.asm  v 34.9   Copyright 1988 Commodore-Amiga, Inc.
  3. *------
  4. *------ Conditional assembly flags
  5. *------ ASTART:   1=Standard Globals Defined    0=Reentrant Only
  6. *------ WINDOW:   1=AppWindow for WB startup    0=No AppWindow code
  7. *------ XNIL:     1=Remove Rstartup NIL: init   0=Default Nil: WB Output
  8. *------ DEBUG:    1=Set up old statics for Wack 0=No extra statics
  9.  
  10. * Flags for  [A]start  AWstart  Rstart  RWstart  RXstart
  11. * ASTART         1        1       0        0        0
  12. * WINDOW         0        1       0        1        0
  13. * XNIL           0        0       0        0        1
  14. * DEBUG          0        0       0        0        0
  15.  
  16. ASTART    SET   1
  17. WINDOW    SET   0
  18. XNIL      SET   0
  19. DEBUG     SET   0
  20.  
  21. ;------   Flag WB output initialization
  22. WBOUT     SET   (ASTART!WINDOW!(1-XNIL))
  23.  
  24. ************************************************************************
  25. *
  26. *   Rstartup.asm --- Reentrant C Program Startup/Exit (CLI and WB)
  27. *                    by C. Scheppner, based on Amiga startup.asm
  28. *                    v34.9  05/25/88
  29. *
  30. *   Copyright (c) 1988 Commodore-Amiga, Inc.
  31. *
  32. *   Title to this software and all copies thereof remain vested in the
  33. *   authors indicated in the above copyright notice.  The object version
  34. *   of this code may be used in software for Commodore Amiga computers.
  35. *   All other rights are reserved.
  36. *
  37. *   NO REPRESENTATIONS OR WARRANTIES ARE MADE WITH RESPECT TO THE
  38. *   ACCURACY, RELIABILITY, PERFORMANCE OR OPERATION OF THIS SOFTWARE,
  39. *   AND ALL SUCH USE IS AT YOUR OWN RISK.  NEITHER COMMODORE NOR THE
  40. *   AUTHORS ASSUME ANY RESPONSIBILITY OR LIABILITY WHATSOEVER WITH
  41. *   RESPECT TO YOUR USE OF THIS SOFTWARE.
  42. *
  43. *
  44. *   RSTARTUP.ASM
  45. *
  46. *      This startup dynamically allocates a structure which includes
  47. *   the argv buffers.  If you use this startup, your code must return
  48. *   to this startup when it exits.  Use exit(n) or final curly brace
  49. *   (rts) to return here.  Do not use AmigaDOS Exit() function.
  50. *   Due to this dynamic allocation and some code consolidation, this
  51. *   startup can make executables several hundred bytes smaller.
  52. *
  53. *       Because a static initialSP variable can not be used, this
  54. *   code depends on the fact that AmigaDOS places the address of
  55. *   the top of our stack in SP and proc->pr_ReturnAddr right before
  56. *   JSR'ing to us.  This code uses pr_ReturnAddr when restoring SP.
  57. *
  58. *       Most versions of Rstartup will initialize a Workbench process's
  59. *   input and output streams (and stdio globals if present) to NIL:
  60. *   if no other form of Workbench output (like WINDOW) is provided.
  61. *   This should help prevent crashes if a user puts an icon on a CLI
  62. *   program, and will also protect against careless stdio debugging
  63. *   or error messages left in a Workbench program.  The code for
  64. *   initializing Workbench IO streams only be removed by assembling
  65. *   Rstartup with ASTART and WINDOW set to 0, and XNIL set to 1.
  66. *
  67. *
  68. *   Some Rstartups which can be conditionally assembled:
  69. *
  70. *      1. Standard Astartup for non-reentrant code
  71. *            Astartup.obj     ASTART=1    WINDOW=0    XNIL=0
  72. *      2. Reentrant startup (no unshareable globals)
  73. *            Rstartup.obj     ASTART=0    WINDOW=0    XNIL=0
  74. *      3. Smaller reentrant-only startup (no NIL: WB init code)
  75. *            RXstartup.obj    ASTART=0    WINDOW=0    XNIL=1
  76. *      4. Standard AWstartup (WB output window) for non-reentrant code
  77. *            AWstartup.obj    ASTART=1    WINDOW=1    XNIL=0
  78. *      5. Reentrant AWstartup (no unshareable globals)
  79. *            RWstartup.obj    ASTART=0    WINDOW=1    XNIL=0
  80. *
  81. *
  82. *   Explanation of conditional assembly flags:
  83. *
  84. *      ASTART (ASTART SET 1) startups will set up and XDEF the
  85. *   global variables _stdin, _stdout, _stderr, _errno and  _WBenchMsg.
  86. *   These startups can be used as smaller replacements for startups
  87. *   like (A)startup.obj and TWstartup.obj.  Startups with ASTART
  88. *   would generally be used for non-reentrant programs, although the
  89. *   startup code itself is still reentrant if the globals are not
  90. *   referenced.
  91. *      Reentrant (ASTART SET 0) startups will NOT set up or
  92. *   XDEF the stdio and WBenchMsg globals.  This not only makes the
  93. *   startup slightly smaller, but also lets you know if your code
  94. *   is referencing these non-reentrant globals (you will get an
  95. *   unresolved external reference when you link).
  96. *
  97. *      WINDOW (WINDOW SET 1) startups use an XREF'd CON: string
  98. *   named AppWindow, defined in your application, to open a stdio
  99. *   console window when your application is started from Workbench.
  100. *   For non-reentrant programs, this window can be used for normal
  101. *   stdio (printf, getchar, etc).  For reentrant programs the window
  102. *   is Input() and Output().  WINDOW is useful when adding Workbench
  103. *   capability to a stdio application, and also for debugging other
  104. *   Workbench applications.  To insure that applications requiring
  105. *   a window startup are linked with a window startup, the label
  106. *   _NeedWStartup can be externed and referenced in the application
  107. *   so that a linker error will occur if linked with a standard
  108. *   startup.
  109. *
  110. *       example:   /* Optional safety reference to NeedWStartup */
  111. *                    extern UBYTE  NeedWStartup;
  112. *                    UBYTE  *HaveWStartup = &NeedWStartup;
  113. *                  /* Required window specification */
  114. *                    char AppWindow[] = "CON:30/30/200/150/MyProgram";
  115. *                    ( OR  char AppWindow[] = "\0";  for no window )
  116. *
  117. *
  118. *      XNIL (XNIL SET 1) allows the creation of a smaller Rstartup
  119. *   by removing the code that initializes a Workbench process's
  120. *   output streams to NIL:.  This flag can only remove the code
  121. *   if it is not required for ASTART or WINDOW.
  122. *
  123. *      DEBUG (DEBUG SET 1) will cause the old startup.asm statics
  124. *   initialSP, dosCmdLen and dosCmdBuf to be defined and initialized
  125. *   by the startup code, for use as debugging symbols when using Wack.
  126. *
  127. *
  128. *   RULES FOR REENTRANT CODE
  129. *
  130. *      - Make no direct or indirect (printf, etc) references to the
  131. *        globals _stdin, _stdout, _stderr, _errno, or _WBenchMsg.
  132. *
  133. *      - For stdio use either special versions of printf and getchar
  134. *        that use Input() and Output() rather than _stdin and _stdout,
  135. *        or use fprintf and fgetc with Input() and Output() file handles.
  136. *
  137. *      - Workbench applications must get the pointer to the WBenchMsg
  138. *        from argv rather than from a global extern WBenchMsg.
  139. *
  140. *      - Use no global or static variables within your code.  Instead,
  141. *        put all former globals in a dynamically allocated structure, and
  142. *        pass around a pointer to that structure.  The only acceptable
  143. *        globals are constants (message strings, etc) and global copies
  144. *        of Library Bases to resolve Amiga.lib references.  Your code
  145. *        must return all OpenLibrary's into non-global variables,
  146. *        copy the result to the global library base only if successful,
  147. *        and use the non-globals when deciding whether to Close any
  148. *        opened libraries.  
  149. *
  150. *
  151. *   By Carolyn Scheppner
  152. *   Based on the following source
  153. ************************************************************************
  154. *
  155. * Source Control:
  156. * --------------
  157. *
  158. * $Header: startup.asm,v 1.1 86/08/25 12:50:07 root Exp $
  159. *
  160. * $Locker: root $
  161. *
  162. * $Log:   startup.asm,v $
  163. * Revision 1.1  86/08/25  12:50:07  root
  164. * Initial revision
  165. *
  166. * Revision 33.6  86/06/12  10:34:36  neil
  167. * changed so any version of dos is OK
  168. * 
  169. * Revision 33.5  86/06/11  19:03:47  neil
  170. * fixed CloseLibrary if open of dos failed
  171. * 
  172. * Revision 33.4  86/06/09  16:48:59  neil
  173. * now processes escapes also
  174. * 
  175. * Revision 33.3  86/06/09  16:18:12  neil
  176. * another checkpoint -- quoted strings now work
  177. * 
  178. * Revision 1.1  85/11/23  13:49:01  neil
  179. * Initial revision
  180. * 
  181. *
  182. ************************************************************************
  183.  
  184.  
  185. ******* Included Files *************************************************
  186.  
  187.    INCLUDE "exec/types.i"
  188.    INCLUDE "exec/alerts.i"
  189.    INCLUDE "exec/memory.i"
  190.    INCLUDE "libraries/dos.i"
  191.    INCLUDE "libraries/dosextens.i"
  192.    INCLUDE "workbench/startup.i"
  193.  
  194.  
  195. ******* Macros *********************************************************
  196.  
  197. xlib   macro
  198.    xref   _LVO\1
  199.    endm
  200.  
  201. callsys   macro
  202.    CALLLIB   _LVO\1
  203.    endm
  204.  
  205. ******* Imported *******************************************************
  206.  
  207.    xref   _AbsExecBase
  208.    xref   _Input
  209.    xref   _Output
  210.    xref   _main         ; C code entry point
  211.  
  212.    IFGT  WINDOW
  213.    xref   _AppWindow    ; CON: spec in application for WB stdio window
  214.    xdef   _NeedWStartup ; May be externed and referenced in application
  215.    ENDC  WINDOW
  216.  
  217.    xlib   Alert
  218.    xlib   AllocMem
  219.    xlib   FindTask
  220.    xlib   Forbid
  221.    xlib   FreeMem
  222.    xlib   GetMsg
  223.    xlib   OpenLibrary
  224.    xlib   CloseLibrary
  225.    xlib   ReplyMsg
  226.    xlib   Wait
  227.    xlib   WaitPort
  228.  
  229.    xlib   CurrentDir
  230.    xlib   Open
  231.    xlib   Close
  232.  
  233. ******* Exported *******************************************************
  234.  
  235. *----- These globals are set up for standard startup code only
  236.    IFGT  ASTART
  237.    xdef   _stdin
  238.    xdef   _stdout
  239.    xdef   _stderr
  240.    xdef   _errno
  241.    xdef   _WBenchMsg
  242.    ENDC  ASTART
  243.  
  244. *----- These globals available to normal and reentrant code
  245.  
  246.    xdef   _SysBase
  247.    xdef   _DOSBase
  248.    xdef   _exit         ; standard C exit function
  249.  
  250.  
  251. ***** Startup Variables structure **********************************
  252.  
  253.   STRUCTURE   SVAR,0
  254.    LONG     sv_DOSBase
  255.    LONG     sv_dosCmdLen
  256.    LONG     sv_dosCmdBuf
  257.    LONG     sv_WBenchMsg
  258.    LONG     sv_WbOutput
  259.    LONG     sv_Reserved1
  260.    LONG     sv_Reserved2
  261.    STRUCT   sv_argvArray,32*4
  262.    STRUCT   sv_argvBuffer,256
  263.   LABEL    SV_SIZEOF
  264.  
  265. ************************************************************************
  266. *
  267. *   Standard Program Entry Point
  268. *
  269. ************************************************************************
  270. *
  271. * Entered with  d0=dosCmdLen  a0=dosCmdBuf
  272. *
  273. * calls  main (argc, argv)
  274. *        int  argc;
  275. *        char *argv[]; 
  276. *
  277. * On Workbench startup, argc=0, argv=WBenchMsg
  278. ************************************************************************
  279.  
  280. startup:
  281.  
  282.    IFGT DEBUG
  283.       move.l   SP,initialSP
  284.       move.l   d0,dosCmdLen
  285.       move.l   a0,dosCmdBuf
  286.    ENDC DEBUG
  287.  
  288.       movem.l  d0/a0,-(sp)
  289.  
  290.       ;------ get Exec's library base pointer:
  291.       movea.l  _AbsExecBase,a6
  292.       move.l   a6,_SysBase
  293.  
  294.       ;------ alloc the argument structure
  295.       move.l   #SV_SIZEOF,d0
  296.       move.l   #(MEMF_PUBLIC!MEMF_CLEAR),d1
  297.       callsys  AllocMem
  298.       move.l   d0,a1             ;allocation to a1
  299.       movem.l  (sp)+,d0/a0       ;d0/a0 and stack to initial state
  300.  
  301.       cmpa.l   #0,a1             ;did we get memory for variables ?
  302.       bne.s    gotmem            ;yes
  303.       moveq.l  #RETURN_FAIL,d0   ;no
  304.       ;------ NOTE:  Exiting here if can't get arg memory
  305.       ;------ Normal exits dependent on ptr to arg memory on stack
  306.       rts
  307.  
  308. gotmem:
  309.       move.l   a1,a5               ;Keep a5 as ptr to SVAR structure
  310.       move.l   a5,-(sp)            ;Put a5 on stack next to Return addr
  311.       move.l   d0,sv_dosCmdLen(a5) ;Save dos command buf len
  312.       move.l   a0,sv_dosCmdBuf(a5) ;     dos command buf ptr
  313.  
  314.       ;------ get the address of our task  a6 = ExecBase
  315.       suba.l   a1,a1               ;clear a1
  316.       callsys  FindTask
  317.       move.l   d0,a4               ;keep task address in a4
  318.  
  319. ;-----------------------------------------------------------------------
  320. ;  Open the DOS library - a6 = AbsExecBase, a5 = svar
  321. ;  If successful, set up Global _DOSBase
  322. ;  Else Alert and exit
  323.  
  324. openDOS
  325.       lea     DOSName(pc),A1     ;dos.library
  326.       moveq.l #0,d0              ;any version
  327.       callsys OpenLibrary
  328.       move.l  d0,sv_DOSBase(a5)
  329.       bne.s   gotDOS             ;Branch if successful
  330.  
  331.       ;----- Else do recoverable alert and exit
  332. noDOS:
  333.       ALERT   (AG_OpenLib!AO_DOSLib)
  334.       moveq.l #100,d0
  335.       bra     exit2
  336.  
  337. gotDOS:
  338.       move.l  d0,_DOSBase        ;Set the global
  339.  
  340. ;-----------------------------------------------------------------------
  341. ;  Branch to Workbench startup code if not a CLI process
  342.  
  343.       tst.l   pr_CLI(A4)
  344.       beq     fromWorkbench
  345.  
  346.  
  347. ;=======================================================================
  348. ;====== CLI Startup Code ===============================================
  349. ;=======================================================================
  350.  
  351. *** Note    a4=Task    a5=SVAR structure    a6=AbsExecBase
  352.  
  353. fromCLI:
  354.       ;------ find command name:
  355.       suba.l   a0,a0
  356.       move.l   pr_CLI(a4),d0
  357.       lsl.l    #2,d0      ; bcpl pointer conversion
  358.       move.l   cli_CommandName(a0,d0.l),d0
  359.       lsl.l    #2,d0      ; bcpl pointer conversion
  360.  
  361.       ;------ create buffer and array:
  362.       movem.l   a2/a3,-(sp)
  363.       lea   sv_argvBuffer(a5),a2
  364.       lea   sv_argvArray(a5),a3
  365.  
  366.       ;------ fetch command name:
  367.       move.l   d0,a0
  368.       moveq.l  #0,d0
  369.       move.b   (a0)+,d0   ; size of command name
  370.       clr.b    0(a0,d0.l)   ; terminate the string
  371.       move.l   a0,(a3)+
  372.  
  373.       ;------   collect parameters:
  374.       move.l   sv_dosCmdLen(a5),d0
  375.       move.l   sv_dosCmdBuf(a5),a0
  376.  
  377.       ;------ null terminate the string, eat trailing garbage
  378.       lea     0(a0,d0.l),a1
  379. stripjunk:
  380.       cmp.b   #' ',-(a1)
  381.  
  382.       ;-- jimm: 8/25/86: per kodiak's recommendation
  383.       ; bls.s   stripjunk
  384.       dbhi   D0,stripjunk
  385.  
  386.       clr.b   1(a1)
  387.  
  388. newarg:
  389.       ;------ skip spaces
  390.       move.b   (a0)+,d1
  391.       beq.s   parmExit
  392.       cmp.b   #' ',d1
  393.       beq.s   newarg
  394.       cmp.b   #9,d1         ; tab
  395.       beq.s   newarg
  396.  
  397.       ;------ push address of the next parameter
  398.       move.l  a2,(a3)+
  399.  
  400.       ;------ process quotes
  401.       cmp.b   #'"',d1
  402.       beq.s   doquote
  403.  
  404.       ;------ copy the parameter in
  405.       move.b  d1,(a2)+
  406.  
  407. nextchar:
  408.       ;------ null termination check
  409.       move.b  (a0)+,d1
  410.       beq.s   parmExit
  411.       cmp.b   #' ',d1
  412.       beq.s   endarg
  413.  
  414.       move.b  d1,(a2)+
  415.       bra.s   nextchar
  416.  
  417. endarg:
  418.       clr.b   (a2)+
  419.       bra.s   newarg
  420.  
  421. doquote:
  422.       ;------ process quoted strings
  423.       move.b  (a0)+,d1
  424.       beq.s   parmExit
  425.       cmp.b   #'"',d1
  426.       beq.s   endarg
  427.  
  428.       ;------ '*' is the BCPL escape character
  429.       cmp.b   #'*',d1
  430.       bne.s   addquotechar
  431.  
  432.       move.b  (a0)+,d1
  433.       cmp.b   #'N',d1
  434.       beq.s   1$
  435.       cmp.b   #'n',d1
  436.       bne.s   2$
  437.  
  438. 1$:
  439.       ;------ got a *N -- turn into a newline
  440.       moveq   #10,d1
  441.       bra.s   addquotechar
  442.  
  443. 2$:
  444.       cmp.b   #'E',d1
  445.       beq.s   3$
  446.       cmp.b   #'e',d1
  447.       bne.s   addquotechar
  448.  
  449. 3$:
  450.       ;------ got a *E -- turn into a escape
  451.       moveq   #27,d1
  452.  
  453. addquotechar:
  454.       move.b  d1,(a2)+
  455.       bra.s   doquote
  456.  
  457. parmExit:
  458.       ;------ all done -- null terminate the baby
  459.       clr.b   (a2)
  460.       clr.l   (a3)
  461.  
  462.       ;------ compute the # of arguments (argc)
  463.       move.l  a3,d0
  464.       lea.l   sv_argvArray(a5),a3
  465.       sub.l   a3,d0
  466.       lsr.l   #2,d0
  467.  
  468.       movem.l  (sp)+,a2/a3
  469.       pea      sv_argvArray(a5)
  470.       move.l   d0,-(sp)
  471.  
  472.  
  473. *
  474. *  The above code relies on the end of line containing a control
  475. *  character of any type, i.e. a valid character must not be the
  476. *  last.  This fact is ensured by DOS.
  477. *
  478.       
  479.    IFGT ASTART
  480.       ;------ get standard input handle:
  481.       jsr      _Input
  482.       move.l   d0,_stdin
  483.  
  484.       ;------ get standard output handle:
  485.       jsr      _Output
  486.       move.l   d0,_stdout
  487.       move.l   d0,_stderr
  488.    ENDC ASTART
  489.  
  490.       bra      domain
  491.  
  492.  
  493. ;=======================================================================
  494. ;====== Workbench Startup Code =========================================
  495. ;=======================================================================
  496.  
  497. *** Note  a4=Task    a5=SVAR structure    a6=AbsExecBase
  498.  
  499. fromWorkbench:
  500.  
  501. ;-----------------------------------------------------------------------
  502. ; This gets the startup message that workbench will send to us
  503. ; Must get this message before doing any DOS calls
  504.  
  505. waitmsg:
  506.       lea   pr_MsgPort(A4),a0     * our process base
  507.       callsys   WaitPort
  508.       lea   pr_MsgPort(A4),a0     * our process base
  509.       callsys GetMsg
  510.  
  511.       ;------ save the message so we can return it later
  512.       move.l   d0,sv_WBenchMsg(a5)
  513.    IFGT ASTART
  514.       move.l   d0,_WBenchMsg
  515.    ENDC ASTART
  516.  
  517.       ;------ push the message on the stack for wbmain (as argv)
  518.       move.l   d0,-(SP)
  519.       clr.l    -(SP)      indicate: run from Workbench (argc==0)
  520.  
  521.       ;------ put DOSBase in a6 for next few calls
  522.       move.l   sv_DOSBase(a5),a6
  523.  
  524.       ;------ get the first argument
  525.       move.l   d0,a2
  526.       move.l   sm_ArgList(a2),d0
  527.       beq.s    docons
  528.  
  529.       ;------ and set the current directory to the same directory
  530.       move.l   d0,a0
  531.       move.l   wa_Lock(a0),d1
  532.       callsys  CurrentDir
  533.  
  534.  
  535. docons: 
  536.    IFGT WBOUT
  537.  
  538.       ;------ Open NIL: or AppWindow for WB Input()/Output() handle
  539.       ;------ Also for possible initialization of stdio globals
  540.       ;------ Stdio used to be initialized to -1
  541.       ;------ a4 = task, a2 = wbenchmsg, DOSBase still in a6
  542.  
  543.       
  544.    IFGT WINDOW
  545.    ;------ Get AppWindow defined in application
  546.       lea.l    _AppWindow,a0
  547.       cmp.b    #0,(a0)
  548.       bne.s    doOpen         ;Open if not null string
  549.    ENDC WINDOW
  550.  
  551.       
  552.    ;------ Open NIL: if no window provided
  553.       lea.l    NilName(PC),a0
  554.  
  555. doOpen:
  556.    ;------ Open up the file whose name is in a0
  557.    ;------ Note - DOSBase still in a6
  558.       move.l   a0,d1
  559.       move.l   #MODE_OLDFILE,d2 
  560.       callsys   Open 
  561.       tst.l    d0
  562.       beq.s    exit2
  563.  
  564.    ;------ save handle for closing on exit
  565.       move.l   d0,sv_WbOutput(a5)
  566.  
  567.    ;------ d0 now contains handle for Workbench Output
  568.  
  569.    IFGT ASTART
  570.    ;------ set the C input and output descriptors 
  571.       move.l   d0,_stdin
  572.       move.l   d0,_stdout
  573.       move.l   d0,_stderr
  574.    ENDC ASTART
  575.  
  576.    ;------ set the console task (so Open( "*", mode ) will work 
  577.    ;       task pointer still in A4
  578.       move.l   d0,pr_CIS(A4)
  579.       move.l   d0,pr_COS(A4)
  580.       lsl.l    #2,d0 
  581.       move.l   d0,a0 
  582.       move.l   fh_Type(a0),d0
  583.       beq.s    noConTask
  584.       move.l   d0,pr_ConsoleTask(A4)
  585. noConTask:
  586.  
  587.    ENDC WBOUT
  588.  
  589.    ;------ Fall though to common WB/CLI code
  590.  
  591.  
  592. ****************************************************
  593. **                                                **
  594. ** This code now used by both CLI and WB startup  **
  595. **                                                **
  596. ****************************************************
  597.  
  598. domain:
  599.       jsr      _main
  600.       ;----- main didn't use exit(n) so provide success return code
  601.       moveq.l  #RETURN_OK,d0
  602.       bra.s    exit2
  603.  
  604. *******************************************************
  605. **                                                   **
  606. **  C Program exit() Function, return code on stack  **
  607. **                                                   **
  608. *******************************************************
  609.  
  610. _exit:
  611.       move.l   4(SP),d0   ;exit(n) return code to d0
  612.  
  613. exit2:
  614.  
  615.       move.l   d0,d2      ;save return code in d2
  616.  
  617.       ;------ restore initial stack ptr
  618.       ;------ FindTask
  619.       movea.l  _AbsExecBase,a6
  620.       suba.l   a1,a1
  621.       callsys  FindTask
  622.       ;------ get SP as it was prior to DOS's jsr to us
  623.       move.l   d0,a4
  624.       move.l   pr_ReturnAddr(a4),a5
  625.       ;------ subtract 4 for return address, 4 for the a5 we pushed
  626.       suba.l   #8,a5
  627.       ;------ restore sp (stack now contains our a5, then address for rts)
  628.       move.l   a5,sp
  629.       ;------ pull our a5 (= ptr to svar)
  630.       move.l   (sp)+,a5
  631.  
  632.       move.l   d2,-(SP)   ;put return code on stack
  633.  
  634.  
  635.    IFGT WBOUT
  636.    ;----- Close any WbOutput file before closing dos.library
  637.       move.l  sv_WbOutput(a5),d1
  638.       beq.s   noWbOut
  639.       move.l  sv_DOSBase(a5),a6
  640.       callsys Close
  641. noWbOut:
  642.       ;------ Restore a6 = ExecBase
  643.       movea.l _AbsExecBase,a6
  644.     ENDC WBOUT
  645.  
  646.       ;------ ExecBase still in a6
  647.       ;------ Close DOS library if it was opened
  648.       move.l   sv_DOSBase(a5),d0
  649.       beq.s    1$
  650.       move.l   d0,a1
  651.       callsys  CloseLibrary
  652. 1$:
  653.  
  654.       ;------ if we ran from CLI, skip workbench reply
  655.       tst.l   sv_WBenchMsg(a5)
  656.       beq.s   deallocSV
  657.  
  658.       ;------ return the startup message to our parent
  659.       ;------   we forbid so workbench can't UnLoadSeg() us
  660.       ;------   before we are done:
  661.       callsys  Forbid
  662.       move.l   sv_WBenchMsg(a5),a1
  663.       callsys  ReplyMsg
  664.  
  665. deallocSV:
  666.       ;------ deallocate the SVAR structure
  667.       move.l  a5,a1
  668.       move.l  #SV_SIZEOF,d0
  669.       callsys FreeMem     ;a6 still holds AbsExecBase
  670.  
  671.       ;------ this rts sends us back to DOS:
  672.  
  673. exitToDOS:
  674.       move.l   (SP)+,d0
  675.       rts
  676.  
  677.  
  678. ;----- PC relative data
  679.  
  680. DOSName      DOSNAME
  681. NilName      dc.b   'NIL:',0
  682.  
  683. ************************************************************************
  684.  
  685.    DATA
  686.  
  687. ************************************************************************
  688.  
  689. _SysBase     dc.l   0
  690. _DOSBase     dc.l   0
  691.  
  692.    IFGT ASTART
  693. _WBenchMsg   dc.l   0
  694. _stdin       dc.l   0
  695. _stdout      dc.l   0
  696. _stderr      dc.l   0
  697. _errno       dc.l   0
  698.    ENDC ASTART
  699.  
  700.    IFGT DEBUG
  701. initialSP    dc.l   0
  702. dosCmdLen    dc.l   0
  703. dosCmdBuf    dc.l   0
  704.    ENDC DEBUG
  705.  
  706. VerRev       dc.w   34,9
  707.    IFGT ASTART
  708.              dc.b   'A'
  709.    ENDC ASTART
  710.    IFEQ ASTART
  711.              dc.b   'R'
  712.    ENDC ASTART
  713.    IFGT WINDOW
  714. _NeedWStartup:
  715.              dc.b   'W'
  716.    ENDC WINDOW
  717.    IFEQ WBOUT
  718.              dc.b   'X'
  719.    ENDC WBOUT
  720.    IFGT DEBUG
  721.              dc.b   'D'
  722.    ENDC DEBUG
  723.  
  724.    END
  725.  
  726.